home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Libris Britannia 4
/
science library(b).zip
/
science library(b)
/
MEDICAL
/
2608A.ZIP
/
GP.ZIP
/
PRINTDEM.SRC
< prev
next >
Wrap
Text File
|
1990-11-03
|
18KB
|
946 lines
;\|
;NW 10:51:46 AM 15/12/89 |
;THIS PROGRAM ENABLES RP'S AND LABELS TO PRINTED AT THE SAME TIME.
;THIS WILL ONLY OCCUR IF THE PATIENT IS ENTERED A DISPENSING=Y
;FOR THIS TO OPERATE CORRECTLY YOU REQUIRE A PRINTER SOFT-SWITCH DEVICE.
;IN TASINSTL PRINTER CONTROL CODES 10,11,12 ARE USED TO SWITCH PRINTERS.
;11 = PRESCRIPTIONS 12 = LABELS (USING 10 AS DUAL CODE)
FIELDS:
define(S1|A|1||)
define(PN27|A|27||)
define(AD22|A|22||)
define(RESTRICT1|A|25||)
define(RESTRICT2|A|35||)
define(S1PRNT|A|1||)
define(S10|A|10||)
define(N2|N|2|0|)
define(MINUS|N|1||)
define(TIT|A|4||)
define(N3|N|3|0|)
define(N5|N|5|0|)
define(B8|A|8||)
define(N5.2|N|5|2|)
define(A5|A|5||)
define(A8|A|8||)
define(A30|A|30||)
define(B30|A|30||)
define(C30|A|30||)
define(D1|A|1||)
define(AGE|N|5|2|)
define(TD|S|8||)
define(DATERP|S|8||)
define(TDND|S|8||)
define(DATEX|S|8||)
define(REC.NUM|N|8|0|)
define(MEM.PAT.NAME|A|27||)
define(DAY|N|1|0|)
define(DOCTORRP|A|30||)
define(P2|N|2|0|)
define(PUNC2A|N|2|0|)
define(PATIENT1A|A|30||)
define(PUNC1|N|2|0|)
define(TM|A|27||16)
define(N.2.0.P|N|2|0|)
define(P.2.0.1|N|2|0|)
define(P.2.0.2|N|2|0|)
define(P.2.0.3|N|2|0|)
define(PATIENT1|A|30||)
define(PATIENT2|A|30||)
define(X1|A|1||)
define(CHOICE|N|2|0|)
define(YES.NO|A|1||)
define(A78|A|80||)
define(PCTR|N|2|0|)
define(AB|A|5||)
define(LETTER|A|6||)
define(NY|A|1||)
define(MEDCTR|N|1|0|)
define(PATCTR|N|4|0|)
define(Z30|A|30||)
define(P2X|N|1||)
define(RPCTR|N|4||)
define(CODEX1|S|8||)
define(CODEX2|S|8||)
define(CODEX3|S|8||)
date(TD|G)
open(GPSETUP||0|EXIT)
find(B|HEADING|EXIT)
NEWPRINT:
open(PATIENT||1|EXIT)
open(RP||1|EXIT)
open(ABBREV||1|EXIT)
open(RPABBREV||1|EXIT)
TDM:
clrlne(1|25)
clrlne(1|24)
trap(I|I)
gosub CLEARALL
gosub FIELDCLR
gosub TRAPS
mount(RP|S)
trap(U|I)
trap(W|I)
YES.NO = ("")
pmsg(@H;"DO YOU WANT A TEST PRESCRIPTION PRINT?"|1|25|N|Y|S|)
enter(YES.NO|"YN"|||Y|Y|N|40|25|N)
clrlne(1|25)
if YES.NO = ("N") goto MESS
pmsg(@H;"ALIGN PAPER THEN PRESS ANY KEY TO PRINT DUMMY SCRIPT"|1|25|Y|N|S|)
clrlne(1|25)
gosub MOUNTRP
trap(I|S|PRINTSTOP)
PATIENT.NAME = ("THIS SHOULD BE AT NAME")
A30 = ("THIS SHOULD BE ON END LINE")
pblnk(1)
pfmt(1|||N|N|)
pvert(40)
pblnk(1)
pfmt(7|||N|N|)
mount(RP|S)
trap(I|I)
pmsg(@H;"PRINT ANOTHER TEST PRESCRIPTION? Y/N"|1|25|N|N|S|)
enter(YES.NO|"YN"|||Y|Y|N|40|25|N)
clrlne(1|25)
if YES.NO = ("N") goto MESS
goto TDM
MESS:
clrlne(1|25)
gosub TRAPS
gosub CLEARALL
PRINTRPS:
trap(Q|G|RP.EXIT)
trap(C|I)
trap(1|G|PRINT.DEM)
PRINTRP:
PAT.NAMEX:
mount(RP|S)
clrlne(1|25)
gosub CLEARALL
gosub FIELDCLR
PAT.NAMEX2:
trap(Q|G|RP.EXIT)
trap(F|D)
trap(N|D)
trap(L|G|DEMLOCK)
trap(M|D)
trap(R|D)
pmsg("<End>key to print demands"|50|24|N|N|S|)
find(B|RECORD.NUMBER|EXIT)
clr(PATIENT|B)
clr(RP|B)
enter(PATIENT.NAME|||PAT.NAMEX|Y|Y|N|||N)
clrlne(50|24)
find(G|PATIENT.NAME|PAT.NAMEX2)
gosub STATUS
RP.REF = (RECORD.NUMBER)
find(M|RP.REF|PAT.NAMEX2)
if RP.REF <> (RECORD.NUMBER) goto PAT.NAMEX2
saves(1)
trap(Q|I)
trap(R|I)
trap(N|I)
trap(M|I)
rev
window(1|24|2|30)
pmsg("THIS PATIENT? Y/N:"|1|1|N|N|S|)
PRINTP = ("Y")
enter(PRINTP|"YN"|||Y|Y|N|20|1|N)
frg
redsp(1)
trap(Q|G|RP.EXIT)
if PRINTP <> ("Y") goto PAT.NAMEX2
save(PATIENT|N|N|PAT.NAMEX)
find(M|RECORD.NUMBER||)
RECNUM:
RP.REF = (RECORD.NUMBER)
find(M|RP.REF|DEL.PRINTP)
if AUTO.ON.DEMAND = ("A") goto NEXTRP
RECORD.NUMBER = (RP.REF)
find(M|RECORD.NUMBER|PAT.NAMEX)
INCLUDE?:
saves(1)
trap(Q|I)
rev
window(1|24|2|30)
pmsg("INCLUDE THIS RP Y/N?"|1|1|N|N|S|)
PRINTR = ("Y")
enter(PRINTR|"YN"|||Y|Y|N|23|1|N)
frg
redsp(1)
trap(Q|G|RP.EXIT)
if CONTROL = ("N") goto CONTROL1
if ISS.RESTRICT = ("Y") do
{
if RP.NEXT.DUE > (TD+3) do
{
gosub RESTSCR
goto NEXTRP
}
}
CONTROL1:
if PRINTR <> ("Y") goto NEXTRP
save(RP|N|N|PAT.NAMEX2)
NEXTRP:
find(N|RP|PAT.NAMEX2)
if RP.REF <> (RECORD.NUMBER) goto PAT.NAMEX2
if AUTO.ON.DEMAND = ("A") goto NEXTRP
goto INCLUDE?
;PRINT ON DEMAND RPS AND CLEAR THE FLAGS|
PRINT.DEM:
saves(1)
trap(Q|I)
rev
window(1|24|2|45)
D1 = ("N")
pmsg("OWN DOCTOR <Y> OR DR. OF DAY SIGNING <N>:"|1|1|N|N|S|)
enter(D1|"YN"|||Y|Y|N|43|1|N)
frg
redsp(1)
trap(Q|G|RP.EXIT)
trap(I|S|PRINTSTOP)
trap(L|S|RECLOCK)
gosub MOUNTRP
N2 = (0)
S1 = ("1")
S1PRNT = ("D")
P2 = (0)
PRINTP = ("Y")
find(M|PRINTP|PAT.NAMEX)
PRINFIND:
RP.REF = (RECORD.NUMBER)
find(M|RP.REF|NEXTPRINP)
if PRINTR <> ("Y") goto FINDNEXTR
gosub PRINT
NEXTPRINR:
RP.REF = (RECORD.NUMBER)
FINDNEXTR:
find(N|RP|ENDPRINT?)
if RP.REF <> (RECORD.NUMBER) goto ENDPRINT?
if PRINTR <> ("Y") goto FINDNEXTR
S1 = (1)
gosub PRINT
goto NEXTPRINR
NEXTPRINP:
PRINTP = (" ")
save(PATIENT|N|N|PAT.NAMEX)
find(M|RECORD.NUMBER||)
PRINTP = ("Y")
find(M|PRINTP|XPRINT)
if PRINTP <> ("Y") goto XPRINT
N2 = (0)
P2 = (0)
S1 = ("1")
S1PRNT = ("D")
goto PRINFIND
PRINT:
trap(I|S|PRINTSTOP)
clr(GPSETUP|B)
find(B|HEADING|EXIT)
if N2 = (0) gosub SHEADING
DATERP = (RP.NEXT.DUE+RP.DAYS.SUPPLY)
RESTRICT1 = ("")
RESTRICT2 = ("NEXT DUE:")
pblnk(1)
just(RESTRICT2|R)
if CONTROL = ("N") goto ELSE
if RESTRICT.NO > (2) goto ELSE
if ISS.RESTRICT = ("Y") do
{
A30 = (MEDICATION)
just(A30|R)
S10 = (QUANTITY)
just(S10|R)
if RESTRICT.NO = (2) do
{
RESTRICT1 = (":ONLY ONE MORE RPT IS")
RESTRICT2 = ("ALLOWED.PLEASE SEE YOUR DR BEFORE:")
trim(RESTRICT1|T)
trim(RESTRICT2|T)
pfmt(7|||N|N|)
pfmt(8|||N|N|)
pfmt(9|||N|N|)
goto ELSEX
}
if RESTRICT.NO = (1) do
{
RESTRICT1 = (":THIS IS THE LAST ISSUE.")
RESTRICT2 = ("YOU MUST SEE YOUR DR BEFORE:")
trim(RESTRICT1|T)
trim(RESTRICT2|T)
pfmt(7|||N|N|)
pfmt(8|||N|N|)
pfmt(9|||N|N|)
goto ELSEX
}
if RESTRICT.NO <= (0) do
{
MINUS = (MINUS+1)
RESTRICT1 = (" RESTRICTION REACHED!")
RESTRICT2 = ("INFORM DOCTOR IMMEDIATELY")
just(A30|R)
pfmt(28|||N|N|)
pfmt(29|||N|N|)
pblnk(1)
goto ELSEX
}
}
else
{
goto ELSE
}
ELSE:
A30 = (MEDICATION)
S10 = (QUANTITY)
pfmt(7|||N|N|)
pfmt(8|||N|N|)
pfmt(9|||N|N|)
ELSEX:
N2 = (N2+1)
gosub UPDT.LIST
if N2 = (5) gosub ENDPRINT
ret
ENDPRINT:
P2X = (N2-MINUS)
MINUS = (0)
LOOPER:
if N2 <> (5) do
{
pfmt(30|||N|N|)
pblnk(3)
N2 = (N2+1)
goto LOOPER
}
pvert(31)
if S1 = ("0") do
{
pfmt(14|||N|N|)
}
else
{
pfmt(15|||N|N|)
}
pblnk(2)
60:
if S1PRNT = ("A") do
{
pfmt(17|||N|N|)
if D1 = ("Y") do
{
DAY = (DOCTOR)
RPDOCTOR = (RPDOCTOR[DAY])
DOCTORRP = (RPDOCTOR)
pfmt(19|||N|N|)
}
else
{
DAY =day(TDND)
RPDOCTOR = (RPDOCTOR[DAY])
DOCTORRP = (RPDOCTOR)
pfmt(19|||N|N|)
}
}
else
{
pfmt(18|||N|N|)
if D1 = ("Y") do
{
DAY = (DOCTOR)
RPDOCTOR = (RPDOCTOR[DAY])
DOCTORRP = (RPDOCTOR)
pfmt(20|||N|N|)
}
else
{
DAY =day(TD)
RPDOCTOR = (RPDOCTOR[DAY])
DOCTORRP = (RPDOCTOR)
pfmt(20|||N|N|)
}
}
pfmt(21|||N|N|)
pfmt(22|||N|N|)
TESTDISP:
if DISPENSING = ("Y") do
{
pfmt(27|||N|N|)
}
EJECT:
pvert(41)
pblnk(1)
RPCTR = (RPCTR+1)
pmsg("Number of RP's printed=";RPCTR|1|24|N|N|S|)
PUNC2A = (0)
B8 = ("A")
N2 = (0)
S1 = ("0")
RETURN:
ret
UPDT.LIST:
RP.NEXT.DUE = (RP.NEXT.DUE+RP.DAYS.SUPPLY)
ISSUE.NO = (ISSUE.NO+1)
if CONTROL = ("N") goto CONTROL2
if ISS.RESTRICT <> ("Y") do
{
RESTRICT.NO = (0)
}
else
{
RESTRICT.NO = (HOW.MANY.ISSUES-ISSUE.NO)
}
CONTROL2:
ISSUE.1 = (TDND)
if S1PRNT = ("D") do
{
ISSUE.1 = (TD)
RP.NEXT.DUE = (TD+RP.DAYS.SUPPLY)
}
SAVERPX:
if S1PRNT = ("A") do
{
DATERP = (RP.NEXT.DUE)
}
else
{
if DISPENSING = ("Y") do
{
PRINTR = ("L")
}
else
{
PRINTR = ("")
}
}
save(RP|N|Y|)
ret
SEXIST:
TIT = ("")
if SEX = ("M") then TIT = ("Mr.")
if SEX = ("F") do
{
if MARITAL.STATUS = ("M") do
{
TIT = ("Mrs.")
}
else
{
TIT = ("Ms.")
}
}
if SEX = ("") then TIT = ("Ms.")
trim(TIT|T)
ret
SHEADING:
pblnk(1)
gosub SEXIST
pfmt(1|||N|N|)
LINE2:
P2 = (0)
pblnk(3)
pfmt(4|||N|N|)
pblnk(1)
pfmt(6|||N|N|)
pblnk(2)
ret
ENDPRINT?:
if N2 <> (0) gosub ENDPRINT
if S1PRNT = ("A") do
{
if CONTROL = ("N") goto CONTROL3
gosub RESTDEL
trap(I|I)
goto NEWPRINT
}
goto NEXTPRINP
CONTROL3:
trap(I|I)
goto NEWPRINT
MOUNTRP:
mount(AUTORP|R|P)
pchr(P|10)
pchr(P|11)
pchr(P|4)
pchr(P|1)
pset(132|42|42)
ret
TRAPS:
trap(I|D)
trap(Q|G|EXIT)
trap(3|I)
trap(7|S|HOME)
trap(9|S|PGUP)
trap(S|I)
trap(D|I)
trap(R|I)
trap(F|I)
trap(N|I)
trap(M|I)
trap(J|I)
trap(U|D)
trap(W|D)
trap(1|I)
trap(L|S|RECLOCK)
ret
CLEARALL:
clr(PATIENT|B)
clr(RP|B)
ret
;MOUNT REPORT RPLABELS|
RPLABSCR:
mount(RPLABELS|R|P)
pchr(P|10)
pchr(P|12)
pchr(P|4)
pchr(P|1)
pset(79|13|13)
ret
EJECTION:
ptof
ret
;LABEL PRINTING ROUTINES FOR DEMANDS AND DISPENSING|
PRINTPX:
trap(I|S|PRINTSTOP)
gosub SEXIST
gosub NEWX
if X1 = ("X") do
{
TDND = (TD)
}
else
{
TDND = (RP.NEXT.DUE)
}
S10 = (QUANTITY)
C30 = (DIRECTIONS)
A30 = (MEDICATION)
just(Z30|C)
just(LABELS|C)
just(S10|C)
just(C30|C)
just(A30|C)
just(DOSE|L)
pfmt(1|||N|N|)
pfmt(4|||N|N|)
pfmt(5|||N|N|)
pfmt(6|||N|N|)
pfmt(7|||N|N|)
pfmt(8|||N|N|)
pfmt(9|||N|N|)
pfmt(10|||N|N|)
pfmt(11|||N|N|)
pblnk(4)
trap(I|I)
ret
NEWX:
NY = (" ")
PATIENT1A = (PATIENT.NAME)
trim(PATIENT1A|T)
PUNC1 =loc(","|PATIENT1A|1||27)
N.2.0.P =siz(A|PATIENT.NAME)
P.2.0.1 = (PUNC1-1)
PATIENT2 =mid(PATIENT.NAME|1|P.2.0.1|)
P.2.0.2 = (PUNC1+2)
P.2.0.3 = (N.2.0.P-P.2.0.2+1)
PATIENT1 =mid(PATIENT1A|P.2.0.2|P.2.0.3|)
trim(PATIENT1|T)
trim(PATIENT2|T)
Z30 = (TIT+PATIENT1+NY+PATIENT2)
ret
;DEMAND LABEL PRINTING USING RPLABELS|
XPRINT:
clrlne(1|24)
PRINTP = (" ")
ifdup(PATIENT.NAME|G|X1E)
save(PATIENT|N|Y|X1E)
X1E:
gosub CLEARALL
gosub FIELDCLR
trap(I|I)
saves(2)
trap(Q|I)
rev
window(15|24|2|50)
pmsg("DO YOU WANT LABELS FOR THESE RP,S <Y>or<N>?:"|1|1|N|N|S|)
enter(YES.NO|"YN"|||Y|Y|N|45|1|N)
frg
redsp(2)
trap(Q|G|EXIT)
if YES.NO <> ("Y") goto MESSCON
X1 = ("X")
trap(L|S|RECLOCK)
gosub RPLABSCR
PRINTR = ("L")
find(M|PRINTR|MESSCON)
RECORD.NUMBER = (RP.REF)
find(M|RECORD.NUMBER|EXIT)
gosub PRINTPX
XXXX:
PRINTR = (" ")
save(RP|N|N|)
PRINTR = ("L")
find(N|RP|MESSCON)
if PRINTR <> ("L") goto MESSCON
RECORD.NUMBER = (RP.REF)
find(M|RECORD.NUMBER|)
X1 = ("X")
gosub PRINTPX
goto XXXX
MESSCON:
gosub RESTDEL
goto MESS
MENU:
RUN:
TM[1] = (" 1 - AGE-SEX REGIST 01011")
TM[2] = (" 2 - PRINT DEMANDS 01022")
TM[3] = (" 3 - EXIT 01033")
TM[4] = (" 4 - PRINT AUTOS 01044")
menu(30|20|5|23|0|TM|CHOICE|4|22|RUN||"---RP PRINT DEMAND----"|N)
on(CHOICE|G|PATIENT;NEWPRINT;EXIT2|ALL)
RP.EXIT:
gosub TRAPS
goto EXIT
ALL:
run("PRINTALL")
DEL.PRINTP:
RECORD.NUMBER = (RP.REF)
find(M|RECORD.NUMBER||)
PRINTP = ("")
save(PATIENT|N|Y|PAT.NAMEX2)
goto PAT.NAMEX2
PRINTSTOP:
pon(S)
clrlne(1|25)
pmsg("CONTINUE(Y) OR EXIT (N) (Y/N):"|1|12|N|N|S|)
enter(YES.NO|"YN"|||Y|Y|N|35|12|N)
if YES.NO <> ("Y") then run("RP")
pon(P)
ret
RESTSCR:
trap(Q|I)
saves(9)
rev
window(20|15|3|45)
pmsg("THIS RP IS NOT DUE UNTIL:";RP.NEXT.DUE|1|1|N|N|S|)
pmsg("INFORM DOCTOR AS YOU CANT PRINT THIS YET."|1|2|Y|N||)
frg
redsp(9)
trap(Q|G|RP.EXIT)
ret
RESTDEL:
mount(RP|S)
RESTDELX:
RESTRICT.NO = (-1)
find(G|RESTRICT.NO|RESTRET)
if RESTRICT.NO > (-1) goto RESTRET
if ISS.RESTRICT <> ("Y") goto RESTNEXT
del(RP|Y|RESTNEXT)
goto RESTDELX
RESTNEXT:
find(N|RP|RESTPREV)
if RESTRICT.NO > (-1) goto RESTPREV
if ISS.RESTRICT <> ("Y") goto RESTNEXT
del(RP|Y|RESTNEXT)
goto RESTDELX
RESTPREV:
find(P|RP|RESTRET)
if RESTRICT.NO > (-1) goto RESTRET
if ISS.RESTRICT <> ("Y") goto RESTPREV
del(RP|Y|RESTPREV)
goto RESTPREV
RESTRET:
ret
HOME:
pchr(P|10)
pchr(P|12)
for(PCTR|1|13|1)
{
pchr(P|7)
}
ret
PGUP:
pchr(P|10)
pchr(P|11)
for(PCTR|1|42|1)
{
pchr(P|7)
}
ret
FIELDCLR:
S1 = ("")
MINUS = (0)
D1 = ("")
S1PRNT = ("")
S10 = ("")
N2 = (0)
N3 = (0)
N5 = (0)
N5.2 = (0)
A5 = ("")
A8 = ("")
A30 = ("")
B30 = ("")
C30 = ("")
AGE = (0)
DATERP = (0)
TDND = (0)
DATEX = (0)
REC.NUM = (0)
MEM.PAT.NAME = ("")
DAY = ("")
DOCTORRP = ("")
P2 = (0)
PUNC2A = (0)
B8 = ("")
YES.NO = ("")
PCTR = (0)
AB = ("")
LETTER = ("")
NY = ("")
MEDCTR = (0)
PATCTR = (0)
P2X = (0)
CODEX1 = (0)
CODEX2 = (0)
CODEX3 = (0)
ret
LETCLR:
clr(PATIENT|B)
clr(RP|B)
ret
PATIENT:
run("PATIENT")
LETTRAP:
trap(U|I)
trap(W|I)
ret
RUNRP:
run("recmenu")
TRACE:
break
ret
EXIT:
goto MENU
EXIT2:
run("recmenu")
PATLOCK:
pmsg("FILE PATIENT IN USE BY ANOTHER STATION CAN'T LOCK"|20|24|Y|N|S|)
clrlne(1|24)
run("recmenu")
RPLOCK:
pmsg("FILE RP IN USE BY ANOTHER STATION - CAN'T LOCK"|20|24|Y|N|S|)
clrlne(1|24)
run("recmenu")
RECLOCK:
saves(1)
pon(S)
pmsg("THIS RECORD IS LOCKED BY ANOTHER STATION - PRESS RET"|20|24|Y|N|S|)
clrlne(1|24)
redsp(1)
pon(P)
ret
DEMLOCK:
pmsg("RECORD IN USE BY ANOTHER STATION - PRESS RETURN"|10|24|Y|N|S|)
clrlne(1|24)
clr(RP|B)
clr(PATIENT|B)
goto PAT.NAMEX2
STATUS:
if PRINTP = ("") ret
if PRINTP => ("1") do
{
saves(1)
window(2|12|2|76)
pmsg("THERE IS A REGISTRATION PROBLEM WITH THIS PATIENT - CHECK : ";PRINTP|1|1|Y|N|S|)
redsp(1)
}
ret
\STRP
REPEAT PRESCRIBING - DEMAND PRINTING
┌─────────────────────────────────────────────────────────────────────────────┐
│ PATIENT NAME:& < │
│ Address:& & D.O.B.:& │
└─────────┬───────────────────────────────────────┬─────────────────┬─────────┘
│ Auto/on demand? A/D :& │numb.issued:& │
│ Restrictions? Y/N:&for:& issues.│numb.to go :& │
│ Starting.date:& └─────────────────┤
│ Days between issue:& │
│ Last.issue:& │
│ RP.Next.Due:& │
│ Medication @:& < │
│ Warning:& │
│ Strength:& │
│ Dose:& │
│ Directions @:& │
│ Qtity / Type:& /& │
└─────────────────────────────────────────────────────────┘
F1 - HELP @ - ABBREVIATION F3 - CLEAR RP CLEAR PATIENT
HOME - EJECT LABEL * PgUp - EJECT RP * END - PRINT DEMANDS
\
PATIENT.NAME
ADDRESS1
AREA
DATE.OF.BIRTH
AUTO.ON.DEMAND
ISSUE.NO
ISS.RESTRICT
HOW.MANY.ISSUES
RESTRICT.NO
RP.FIRST
RP.DAYS.SUPPLY
ISSUE.1
RP.NEXT.DUE
MEDICATION
RPWARNING
DOSE
QUANTITY
DIRECTIONS
RP.DISP.QTY
RP.WHAT.DISP
\
\R AUTORP
& & : &
& Return all unused tablets to the chemist or Doctor.
& Always bring your Repeat Card with you,thankyou.
& & & &
& & & &
(& )&
&
&
&
& NEXT SCRIP READY TO COLLECT ON: &
& THIS IS "ON DEMAND" ONLY.
&
&
&
& &
& &
SEE YOUR DOCTOR FOR A CHECK-UP,PLEASE
XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX & &
XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX &
* * * * * & ITEM(S) * * * * * *
\
TIT
PATIENT.NAME
PATIENT.NAME
ADDRESS1
AREA
A30
DOSE
A30
RESTRICT1
S10
DIRECTIONS
RESTRICT2
DATERP
RP.DISP.QTY
RP.WHAT.DISP
TDND
TD
TDND
FPC
DATERP
FPC
DOCTORRP
DOCTORRP
PRADDRESS
P2X
TOWN
P2X
TOWN
A30
RESTRICT1
RESTRICT2
P2X
\
\R RPLABELS
&
&
&
------------------------------
&
& (& ) &
&
&
Keep out of reach of children!
\
Z30
S10
C30
A30
DOSE
RP.DISP.QTY
TDND
LABELS
RPWARNING
\